Régularisation mensuelle progressive

Le calcul des tranches 1 et 2 en tenant compte de la régularisation mensuelle progressive est basé non pas sur le salaire mensuel du salarié mais sur le cumul de son salaire et sur le cumul du plafond de la sécurité sociale.

Calcul de la colonne Brut du mois

A saisir manuellement.

Calcul de la colonne Brut cumulé

La première cellule de la colonne correspondant au mois de janvier peut être saisie manuellement ou bien être rempli en récupérant le montant brut du mois de janvier avec la formule =B5.

Le brut cumulé du mois de février pourrait être calculée en récupérant le brut cumulé du mois de janvier auquel on additionne le brut du mois de février avec la formule =B5+B6.



Attrapez ensuite la poignée de recopie et tirer vers le bas jusqu'au mois de décembre, la dernière cellule de la colonne.

Ces 2 formules peuvent être réunies en une seule de la manière suivante.

=SI(LIGNE()=5;B5 ;C4+B5)



La fonction LIGNE() renvoie, si aucune référence n'est saisie entre ses parenthèses, le numéro de la ligne sur laquelle elle se trouve.

Nous pourrions l'utiliser pour vérifier si la formule se trouve sur la ligne 5, c'est à dire, la première cellule de la colonne correspondant au mois de janvier.

Le test logique dont nous aurions besoin serait LIGNE()=5.

À l'intérieur d'une fonction SI(), nous vérifierions si nous nous trouvons sur la ligne 5, si le test logique renvoie VRAI nous récupérons le brut du mois de janvier, B5, s’il renvoie FAUX, nous prenons le montant brut cumulé précédent C4 auquel nous additionnons le montant brut du mois B5.

La cellule C4 contient le nom de la colonne mais comme nous nous trouvons sur la ligne 5 Excel n’additionnera jamais le brut de janvier au nom de la colonne !!!

La formule sera recopiée vers le bas et fonctionnera pour les autres lignes.

Cependant, tant que les montants de la colonne brut du mois ne sont pas saisis, la colonne Salaire brut cumulé affiche des 0. Pour les intercepter il est possible d'insérer une des formules suivantes :

=SI(B5="";"";SI(LIGNE()=5;B5;C4+B5))

=SI(ESTVIDE(B5);"";SI(LIGNE()=5;B5;C4+B5))

Calcul du cumul du plafond de la sécurité sociale

Première méthode

Dans la première cellule de la colonne nous pouvons saisir manuellement le PMSS ou utiliser la référence de la cellule dans laquelle nous l’avons saisi.

Ensuite il convient d’additionner le contenu de la première ligne de la colonne au PMSS avec une référence absolue.

=G5+$B$2

Recopiez la formule vers le bas. Le cumul va s’afficher jusqu’au mois de décembre.

La cellule G5 doit être saisie en référence relative car en recopiant vers le bas, la formule récupèrera le contenu de la cellule du dessus le cumul précédent du PMSS.

La cellule $B$2 doit être saisi avec une référence absolue pour que la formule additionne toujours au cumul précédent du PMSS le même montant du PMSS saisi dans la cellule unique $B$2 qui ne doit pas varier même si on recopie sa référence vers le bas.

Deuxième méthode

La seconde méthode consiste à réunir dans la même formule le traitement de la première cellule de la colonne et le traitement des cellules suivantes.

Comme précédemment nous utiliserons le test logique ligne()=5 pour vérifier si la formule se trouve sur la ligne 5.

Avec la fonction SI(), si la formule se trouve sur la ligne 5, c’est-à-dire sur la première cellule de la colonne alors nous y écrivons le montant du PMSS se trouvant en $B$2, dans le cas contraire, nous additionnons le résultat du mois précédent au PMSS se trouvant en $B$2.

=SI(LIGNE()=5 ;$B$2 ;G5+$B$2)

Pour afficher le cumul du PMSS uniquement si le salaire est saisi en colonne B ajoutez une fonction SI() comme précédemment.

=SI(B5= "";""; SI(LIGNE()=5 ;$B$2 ;G5+$B$2))

Calcul de la colonne >/<

La régularisation mensuelle progressive se calcul à partir du cumul du salaire brut et du cumul du PMSS.

Cette formule est la plus longue du tableau. Elle doit répondre à la question suivante : « Le cumul du salaire est-il supérieur au cumul du plafond de la sécurité sociale ? ». S’il l’est, la colonne affiche >, sinon <. Cela nous donnera l’information une fois pour toutes et nous évitera d’avoir à faire cette vérification dans les formules qui vont suivre.

Une simple fonction SI() nous aidera à faire cela : =SI(C5>G5 ;">";"<").

La colonne C contient le salaire brut cumulé.

La colonne G contient le Plafond de la sécurité sociale cumulé.

Les signes > et < doivent être affichés uniquement si les colonnes Salaire Brut, cumul du salaire brut et cumul du PMSS sont affichés :

=SI(OU(ESTVIDE(B5);ESTVIDE(C5);ESTVIDE(G5));"";SI(C5>G5;">";"<"))

Comme nous avons fait le nécessaire précédemment pour n’afficher les cumuls du salaire brut et du PMSS que si le salaire brut a été saisi alors nous pouvons nous contenter de faire la formule que si la colonne Salaire Brut a été saisie. Dans ce cas cette formule est suffisante : =SI(B5="";"";SI(C5>G5 ;">";"<")).

Recopiez la formule vers le bas.

Calcul de la tranche 1 cumulée

|  |
| --- |
| Le cumul du salaire est-il supérieurau cumul du plafond de la sécurité sociale ? |
| Si oui | Si non |
| La tranche 1 cumulée est égale au plafond cumulé. | La tranche 1 cumulée est égale au brut cumulé. |

Si le cumul du salaire est supérieur au PMSS cumulé, la tranche 1 cumulée est égale au PMSS cumulé sinon elle est égale au Brut Cumulé.

Nous n’avons pas besoin de vérifier si le cumul du salaire est supérieur au cumul du PMSS car nous avons déjà effectué cette vérification dans la colonne >/<.

Si la colonne affiche > le cumul du salaire est supérieur au cumul du PMSS.

Si la colonne affiche < le cumul du PMSS est supérieur au cumul du salaire.

Si la colonne affiche > la tranche 1 Cumulée est égale au PMSS cumulé, c’est-à-dire la cellule G5, sinon, elle est égale au salaire Cumulé, la cellule C5.

=SI(F5=">" ;G5 ;C5)

La colonne >/< évite d’écrire cette formule =SI(C5>G5 ;G5 ;C5) qui est de la même longueur. C’est à l’utilisateur de décider si l’ajout de la colonne >/< lui est favorable.

Calcul de la tranche 2 cumulée

|  |
| --- |
| Le cumul du salaire est-il supérieurau cumul du plafond de la sécurité sociale ? |
| Si oui | Si non |
| La Tranche 2 cumulée est égale à la différence entre le brut cumulé et le plafond cumulé. | La tranche 2 est égale à 0. |

Si le cumul du salaire est supérieur au cumul du PMSS la tranche 2 cumulée est égale au Salaire Brut Cumulé **MOINS** le PMSS Cumulé, sinon elle est égale 0.

Le Salaire Brut Cumulé se trouve en C5.

Le PMSS Cumulé se trouve en G5.

La formule est : =SI(F5=">";C5-G5 ;0).

Si la colonne >/< n’existait pas, la formule deviendrait =SI(C5>G5;C5-G5;0).

Calcul de la tranche 1 du mois

|  |
| --- |
| La tranche 1 est toujours égale à la différence entre la tranche 1 cumulée de ce mois et la tranche 1 cumulée du mois précédent. |

Tranche 1 = Tranche 1 Cumulée de ce mois **MOINS** Tranche 1 Cumulée du mois précédent.

Si nous nous trouvons dans la ligne 5, c’est-à-dire dans la première cellule de la colonne, au mois de janvier, la Tranche 1 du mois est égale à la Tranche 1 Cumulée, D5, sinon, nous effectuons le calcul suivant, Tranche 1 Cumulée de ce mois **MOINS** Tranche 1 Cumulée du mois précédent.

Une simple fonction SI() nous permettra d’effectuer ce calcul :

=SI(LIGNE()=5;D5;D5-D4)

La formule D5-D4 ne sera jamais exécutée. Excel ne va jamais soustraire le nom de la colonne à la Tranche 1 de janvier car comme la formule se trouve sur la ligne 5 Excel récupèrera la Tranche 1 Cumulée de janvier c’est-à-dire D5, ce n’est qu’en recopiant cette formule qu’il soustraira ces deux montants.

Calcul de la tranche 2 du mois

La tranche 2 du mois est toujours égale à la différence entre la tranche 2 cumulée de ce mois et la tranche 2 cumulée du mois précédent.

Tranche 2 = Tranche 2 Cumulé de ce mois **MOINS** Tranche 2 Cumulée du mois précédent.

Le calcul de la Tranche 2 est similaire à celui de la Tranche 1, à cela prêt qu’il s’effectuera à partir de la colonne H, Tranche 2 Cumulée.

=SI(LIGNE()=5;H5;H5-H4) C’est fini !!!



Résumé

Le calcul des tranches 1 et 2 en tenant compte de la régularisation mensuelle progressive est basé non pas sur le salaire mensuel du salarié mais sur le cumul de son salaire et sur le cumul du plafond de la sécurité sociale.

|  |
| --- |
| Le cumul du salaire est-il supérieurau cumul du plafond de la sécurité sociale ? |
| Si oui | Si non |
| La tranche 1 cumulée est égale au plafond cumulé. | La tranche 1 cumulée est égale au brut cumulé. |
| La Tranche 2 cumulée est égale à la différence entre le brut cumulé et le plafond cumulé. | La tranche 2 est égale à 0. |

Ensuite on calcul la tranche 1 qui est toujours égale à la différence entre la tranche 1 cumulée de ce mois et la tranche 1 cumulée du mois précédent.

La tranche 2 du mois est toujours égale à la différence entre la tranche 2 cumulée de ce mois et la tranche 2 cumulée du mois précédent.



|  |  |
| --- | --- |
| Cellule recopiable vers le bas | Formule |
| C5 | =SI(LIGNE()=5;B5;C4+B5) |
| D5 | =SI(F5=">";G5;C5) |
| E5 | =SI(LIGNE()=5;D5;D5-D4) |
| F5 | =SI(OU(ESTVIDE(B5);ESTVIDE(C5);ESTVIDE(G5));"";SI(C5>G5;">";"<")) |
| G5 | =SI(LIGNE()=5;$B$2;G4+$B$2) |
| H5 | =SI(F5=">";C5-G5;0) |
| I5 | =SI(LIGNE()=5;H5;H5-H4) |