La fonction RECHERCHEV()



1. Utilité de la fonction RECHERCHEV()

La fonction RECHERCHEV() permet d’effectuer une recherche sur la première colonne d’un tableau, la colonne se trouvant à l’extrême gauche. Quand elle trouve l’élément recherché, elle reste sur la même ligne et renvoie une information se trouvant dans une colonne de droite.

Le V signifie « vertical » pour indiquer le sens de sa recherche.

La fonction RECHERCHEH() permet d’effectuer des recherches horizontales.

1. Les méthodes de recherche.

La fonction RECHERCHEV() peut effectuer deux types de recherche.

1. Recherche de correspondance exacte.

Recherche exactement la chaine de caractères demandée. Cette méthode de recherche est parfaitement adaptée pour la recherche d’identifiants uniques (les clés primaires) dans les bases de données.

Un numéro de facture, une référence de produit, un code client ou fournisseur sont des identifiants uniques qui permettent d’identifier des enregistrements dans des tableaux de données.

Une valeur numérique, quand elle est utilisée comme identifiant unique, comme un numéro de matricule servant à identifier les employés d’une société, peut être retrouvée avec ce mode de recherche.

Quand la fonction RECHERCHEV() ne trouve pas l’élément demandé par correspondance exacte elle renvoie l’erreur #N/A.

Lorsque l’élément recherché n’est pas un identifiant unique, la fonction RECHERCHEV() renvoie le premier élément trouvé.



La référence de produit est un identifiant unique qui doit être retrouvé avec le mode de recherche « Correspondance exacte ».

Ici cette référence est sous la forme de texte.

1. Recherche de correspondance approximative ou de valeur approchée.

Recherche d’une valeur numérique. La recherche est effectuée dans la première colonne d’un tableau comportant des montants sous forme de paliers triés dans l’ordre croissant. Tous les montants ne sont pas représentés et quand un montant est recherché, s’il n’est pas trouvé, la fonction RECHERCHEV() renvoie le montant du palier inférieur.

Une image contenant table

Description générée automatiquement

Ce tableau dont la première colonne est triée dans l’ordre croissant peut servir à retrouver le % de remise à appliquer sur une facture en fonction du montant HT avec la « Recherche approximative » ou de « Valeur approchée » qui est adapté pour la recherche de valeurs numériques.

1. Structure de la fonction RECHERCHEV()

=RECHERCHEV ( Valeur à rechercher ; Tableau ; Numéro de la colonne à renvoyer ; Type de recherche )

1. Signification des arguments

Valeur à rechercher : On indiquera la référence de la cellule qui contient la valeur à rechercher.

Tableau : Tableau dans lequel effectuer la recherche sur la première colonne de gauche et contenant dans une colonne à droite, la colonne dans laquelle se trouve l’information à renvoyer.

Numéro de la colonne à renvoyer : La colonne se trouvant à l’extrême gauche du tableau est la colonne dans laquelle s’effectuera la recherche, c’est la colonne numéro 1, la colonne suivante la 2, puis la 3 etc…

Type de recherche : Pour une recherche de correspondance exacte on indiquera FAUX ou 0.

Pour une recherche de valeur approchée ou de correspondance approximative on indiquera VRAI ou 1. Si rien n’est renseigné la fonction RECHERCHEV() utilise par défaut une recherche approximative.

1. Exemple d’utilisation
2. RECHERCHEV() utilisant la méthode de recherche « Correspondance exacte »

Nous voulons utiliser la fonction RECHERCHEV() dans une facture pour afficher la désignation du produit en fonction de sa référence.

Une image contenant table

Description générée automatiquement

Pour faciliter la compréhension de l’utilisation de la fonction, nous avons placé la liste des produits à côté de la facture. Dans la pratique elle se trouvera sur un autre onglet ou un autre classeur. (Voir les références externes sous Excel.)

La formule à appliquer pour afficher la désignation en D15 de la référence saisie en C15 est la suivante : =RECHERCHEV(C15;$J$2:$L$21;2;FAUX)

C15 est la cellule dans laquelle nous allons saisir la référence du produit que nous allons demander à Excel de chercher dans la première colonne de la liste de produits. C15 est une référence relative car nous allons recopier cette formule jusqu’à la fin de la colonne désignation et que nous avons besoin, pour afficher la désignation sur les lignes suivantes, qu’Excel remplace automatiquement C15 par C16, C17 etc…

$J$2:$L$21 est la référence de la liste des produits. C’est une référence absolue. La liste de produits est bloquée avec des dollars pour que nous puissions recopier cette référence vers le bas sans qu’Excel la modifie. Il est important que la recherche se fasse toujours sur la totalité de la liste de produits, or si nous ne mettons pas les symboles $, en recopiant vers le bas, J2:L21 sera remplacé par J3:L22 puis par J4:J23, J5:J24 etc… en excluant des lignes, soit des produits, de la liste de recherche.

2 est le numéro de la colonne dans laquelle se trouve l’information à renvoyer, la colonne Désignation. Pour afficher le prix nous devrions remplacer 2 par 3.

FAUX signifie que nous demandons à Excel d’utiliser la méthode de recherche « Correspondance exacte » pour retrouver exactement la chaîne de caractères, le numéro de référence, indiqué en C15. FAUX peut être remplacé par 0.

Si vous insérez la fonction RECHERCHEV() avant de taper une référence dans la cellule C15, elle renvoie l’erreur #N/A pour signifier que la référence n’a pas été trouvée. Il suffit de saisir en C15 une référence se trouvant dans la liste des produits pour afficher la bonne désignation.

Nous verrons tout à l’heure comment intercepter l’erreur #N/A.

1. RECHERCHEV() utilisant la méthode de recherche « Correspondance approximative »

Nous voulons utiliser la fonction RECHERCHEV() dans une facture pour afficher le pourcentage de remise dans la cellule F27 en fonction du montant « Total HT » saisi dans la cellule G26.

Une image contenant table

Description générée automatiquement

La formule ne devant pas être recopiée, nous n’aurons pas besoin d’utiliser le symbole dollars pour bloquer des références.

La recherche s’effectue dans un tableau comportant dans la première colonne des montants classés dans l’ordre croissant. Ils forment des paliers.

La formule utilisable est la suivante : =RECHERCHEV(G26;N24:O29;2;VRAI)

La cellule G26 contient le montant Total HT de la facture à rechercher dans la première colonne, à l’extrême gauche de notre tableau, qui se trouve dans la plage de cellules N24:O29 et qui est notre argument numéro 2. Comme nous ne devons pas recopier la formule, nous ne mettrons pas de $.

Le 2 correspond au numéro de la colonne contenant l’information à renvoyer. Ici le pourcentage de remise.

VRAI signifie que nous souhaitons qu’Excel effectue une recherche de correspondance approximative. VRAI peut être remplacé par 1 ou par rien du tout car en l’absence de quatrième argument, la fonction RECHERCHEV() effectue une recherche de valeur approchée (approximative).

Ce mode de recherche ne renvoie pas #N/A car une valeur numérique positive saisie en G26 trouvera toujours un pourcentage à renvoyer[[1]](#footnote-1).

Une image contenant table

Description générée automatiquement

N’oubliez pas d’appliquer le format pourcentage à la cellule F27 et d’utiliser une formule de type =G26\*F27 pour afficher le montant de la remise.

1. Intercepter l’affichage de l’erreur #N/A

Il existe plusieurs méthodes pour ne pas afficher l’erreur #N/A lors de la recopie de la fonction RECHERCHEV(), cependant si nous ne connaissons pas les formules de calcul à appliquer, il reste possible de supprimer la fonction RECHERCHEV() des cellules dans lesquelles elle n’est pas utilisée avant l’impression.

1. La fonction SI.NON.DISP()

La fonction SI.NON.DISP() affiche un message, argument 2, si la fonction de recherche insérée en argument 1 renvoie #N/A.

=SI.NON.DISP(RECHERCHEV(C15;$J$2:$L$21;2;FAUX);"")

Les deux guillemets se trouvant en argument 2 sont destinés à ne rien afficher dans la cellule.

Nous pourrions écrire « Désignation non trouvée » en modifiant la formule de la manière suivante mais dans notre facture, il est préférable de ne rien écrire.

=SI.NON.DISP(RECHERCHEV(C15;$J$2:$L$21;2;FAUX);"Désignation non trouvée.")

La fonction SI.NON.DISP() est récente, elle est apparue avec la version 2013 d’Excel.

1. La fonction SI()

La fonction SI() était utilisée avant l’arrivée de la fonction SI.NON.DISP() pour ne pas afficher l’erreur #N/A.

La formule suivante fonctionnait sur Excel 97 sous Windows 95.

=SI(C15="";"";RECHERCHEV(C15;$J$2:$L$21;2;FAUX))

Si la cellule C15 ne contient rien, la fonction SI() n’affiche rien, sinon elle exécute la fonction RECHERCHEV().

Dans la formule suivante ESTVIDE(C15) renvoie VRAI si la cellule C15 est vide.

=SI(ESTVIDE(C15);"";RECHERCHEV(C15;$J$2:$L$21;2;FAUX))

D’autres formules sont possibles que vous retrouverez facilement sur internet.

=SI(C15<>"";RECHERCHEV(C17;$J$2:$L$21;2;FAUX);"")

=SI(ESTERREUR(RECHERCHEV(C17;$J$2:$L$21;2;FAUX));"";RECHERCHEV(C17;$J$2:$L$21;2;FAUX)).

1. La formule affichera #N/A uniquement si vous tapez une valeur négative ou du texte en G26, ce qui ne devrait jamais arriver. [↑](#footnote-ref-1)