
Amortissement linéaire

Sans automatisation



Pas d’automatisation

**Calcul du taux :**

=100%/D5

ou =(100/D5)100 pour ne pas que Excel affiche 1000% car =100/D5 renvoie 10 et le format % multiple par 100.

Attention, cette formule est vite supprimée par mégarde.

**Date de fin d’exercice de la première ligne :**

2 formules, une pour la première ligne et la suivante pour les autres lignes.


Il faut créer la date de fin d’exercice à partir de la date d’achat.

=DATE(ANNEE(D7);12;31)

Pour les autres lignes :

=MOIS.DECALER(B10;12)

Dans cette formule B10 est la date de départ et 12 le nombre de mois à décaler.

**Dotation**

=AMORLINC($D$4;$D$7;$B$10;0;C10;$D$6;4)

Coût : Prix d’achat HT **(Référence absolue)**

Date d’achat **(Référence absolue)**


Première période : Dernier jour de l’année d’achat **(Référence absolue)**

Valeur résiduelle : valeur à la fin de l’amortissement, c’est-à-dire 0 sauf si on estime qu’à la fin de l’amortissement le bien peut être revendu un certain prix.

Périodicité : Rang **(Référence relative)**

Taux : 100/par le nombre d’années d’amortissement **(Référence absolue)**

Base : 4 en Europe c’est-à-dire des mois de 30 jours sur 360 par an.



**Cumul**

On remplace le dernier jour de l’année d’achat par le dernier jour de l’année correspondant à la ligne avec référence relative, ensuite le rang par 0.

=AMORLINC($D$4;$D$7;B10;0;0;$D$6;4)

Variante plus simple :

=D10 pour récupérer la première dotation en E10 puis en E11 =E10+D11.

**VNC**


Date d’achat en référence absolue moins le cumul précédent.

=$D$4-E10

Amortissement linéaire

Avec automatisation





Le but de l’automatisation est d’afficher l’intégralité du tableau d’amortissement à partir du moment où le montant de l’immobilisation, la date d’achat et le nombre d’années seront saisis.

Nous mettrons toutes les formules dans la fonction si suivante :

=SI(OU(D4="";D5="";D7="");"";FORMULE)

**Calcul du taux :**

=SI(OU(D4="";D5="";D7="");"";100%/D5)

ou =(100/D5)100 pour ne pas que Excel affiche 1000% car =100/D5 renvoie 10 et le format % multiple par 100.

Je ne recopie pas la formule donc j’utilise des références relatives.

Attention, cette formule est vite supprimée par mégarde.

**Date de fin d’exercice :**

Commencer toujours par

=SI(OU($D$4="";$D$5="";$D$7="");"";

J’utilise des références absolues car la formule sera recopiée.

La fonction LIGNE() renvoie le numéro de la ligne dans lequel on se trouve.

SI(LIGNE()>10+$D$5;"";

**Si je me retrouve sur une ligne strictement supérieure > à la ligne 10 plus le nombre d’années d’amortissement** alors je n’affiche rien. Attention à bien mettre > et non >= car la ligne 10 ne doit pas être compté, cela tiendra compte d’une ligne supplémentaire pour la dernière année qui est ce qu’il reste de la première année.

SI(LIGNE()=10;DATE(ANNEE($D$7);12;31);

**Si c’est la première ligne du tableau** je crée une date de fin d’année à partir de la date d’achat qui ici est en référence absolue.

La fonction DATE() crée une date avec DATE(ANNÉE ; MOIS ; JOUR).

MOIS.DECALER(B9;12))))

Sinon je décale la date du dessus de 12 mois. B9 n’est pas une date, cette référence sert seulement à récupérer la date du dessus mais comme la première date du tableau est déjà interceptée, à la recopie vers le bas, la formule fonctionnera.


=SI(OU($D$4="";$D$5="";$D$7="");"";

SI(LIGNE()>10+$D$5;"";

SI(LIGNE()=10;DATE(ANNEE($D$7);12;31);

MOIS.DECALER(B9;12))))

Intégralité de la formule.

**Dotation**

=SI(OU($D$4="";$D$5="";$D$7="");"";

SI(LIGNE()<=10+$D$5;

AMORLINC($D$4;$D$7;$B$10;0;C10;$D$6;4);

""))

SI(LIGNE()<=10+$D$5; signifie « si la ligne dans laquelle je me trouve est inférieure ou égale à la ligne numéro 10 qui est la première année plus le nombre d’années d’amortissements ».

Coût : Prix d’achat HT **(Référence absolue)**

Date d’achat **(Référence absolue)**


Première période : Dernier jour de l’année d’achat Date de la première ligne du tableau. **(Référence absolue)**.

Valeur résiduelle : valeur à la fin de l’amortissement, c’est-à-dire 0 sauf si on estime qu’à la fin de l’amortissement le bien peut être revendu un certain prix.

Périodicité : Rang **(Référence relative)**

Taux : 100%/par le nombre d’années d’amortissement **(Référence absolue)**

Base : 4 en Europe c’est-à-dire des mois de 30 jours sur 360 par an.



**Cumul**

On remplace le dernier jour de l’année d’achat par le dernier jour de l’année correspondant à la ligne avec référence relative, ensuite le rang par 0.

=SI(OU($D$4="";$D$5="";$D$7="");"";

SI(LIGNE()<=10+$D$5;

AMORLINC($D$4;$D$7;B10;0;0;$D$6;4);

""))

Il existe une variante.

=SI(OU($D$4="";$D$5="";$D$7="");"";

SI(LIGNE()>10+$D$5;"";

SI(LIGNE()=10;D10;E9+D10)))

**VNC**

Date d’achat en référence absolue moins le cumul précédent.

Si le numéro de la ligne dans lequel je me trouve est inférieur à la ligne 10 plus le nombre d’années alors Prix d’achat en référence absolue moins le cumul de la ligne sinon ne rien afficher.

SI(LIGNE()<=10+$D$5;$D$4-E10;""))

Formule complète :

=SI(OU($D$4="";$D$5="";$D$7="");"";

SI(LIGNE()<=10+$D$5;$D$4-E10;""))

Contrôle de la saisie d’un journal autre que les opérations diverses



Le compte est sélectionné avec une liste déroulante.

Le libellé est affiché à l’aide de RECHERCHEV() ou RECHERCHEX().

Dans le libellé 2 vous écrivez ce que vous voulez.

Les colonnes D et C sont à saisir.

Formule de la colonne « Contrôle » :

Dans Excel Alt + touche Entrée permet de revenir à la ligne dans la cellule et rendre les formules plus lisibles.

Formule intégrale :

=SI(ET(ESTVIDE(E5);ESTVIDE(F5));"";

SI(

ET(

RECHERCHEV(B5;Paramètres!$A$3:$C$5;3;FAUX)="D";

ESTVIDE(F5);

NON(ESTVIDE(E5)));

"ok";

SI(

ET(RECHERCHEV(B5;Paramètres!$A$3:$C$5;3;FAUX)="C";

ESTVIDE(E5);

NON(ESTVIDE(F5)));

"ok";

"Erreur")))

Explications de la formule.

Si les deux cellules D et C sont vides on affiche rien.

=SI(ET(ESTVIDE(E5);ESTVIDE(F5));"";

Si la fonction RECHERCHEV() renvoie D et que la colonne C F5 est vide et que la colonne D E5 n’est pas vide alors j’affiche « ok » dans la cellule sinon j’affiche « Erreur ».

SI(

ET(

RECHERCHEV(B5;Paramètres!$A$3:$C$5;3;FAUX)="D";

ESTVIDE(F5);

NON(ESTVIDE(E5)));

"ok";

Sinon

Si la fonction RECHERCHEV() renvoie C et que la colonne D E5 est vide et que la colonne c F5 n’est pas vide alors j’affiche « ok » sinon « Erreur ».

SI(

ET(RECHERCHEV(B5;Paramètres!$A$3:$C$5;3;FAUX)="C";

ESTVIDE(E5);

NON(ESTVIDE(F5)));

"ok";

"Erreur")))

Il est possible de remplacer ok par ✓🗶 en appliquant la police Winding.

✓ Winding = ü Arial

🗶 Winding = û Arial

On peut aussi afficher ü en vert et û en rouge avec la mise en forme conditionnelle.

Pointage d’un rapprochement bancaire sous Excel



Le pointage s’effectue sur la feuille de pointage.

1. Reporter les soldes au début du mois et à la fin du mois dans le tableau Feuille de pointage.
2. Reporter les mouvements de la banque sur la feuille de pointage ainsi que les mouvements du compte 512. (Pas les soldes)
3. Trier le tableau sur la colonne Réf de chèques.
4. Effectuer un pointage de haut en bas sur les références de chèques, puis de bas en haut puis tout regrouper dans une colonne.
5. Dans un endroit quelconque de la feuille, faire la somme des débits qui ont été pointés.

=SOMME.SI(Pointage général ; « x » ;D)

Attention, ne pas pointer avec \* car c’est un caractère générique. Utiliser par exemple x. Idem pour les crédits. Calculer l’écart.

1. S’il y a un écart, dépointer les montants erronés. Éventuellement, effectuer un autre pointage de haut en bas puis de bas en haut s’il y a beaucoup de montants.
2. Faire un copier coller des lignes pointées vers une autre feuille du classeur. Éventuellement, faire la somme des colonnes pour vérifier qu’il y a égalité.
3. Supprimer les lignes vides de la feuille de pointage.
4. Vérifier les soldes. Solde BQ +C – D et Solde 512 – D + C.
5. Passer les écritures correctives en compta.
6. S’il y a trop de lignes à rapprocher, effectuer le rapprochement bancaire par semaine en utilisant le solde à la fin de la semaine.